Excel cho Microsoft 365 Excel 2019 Excel 2016 Excel 2013 Excel 2010 Xem
thêm...Ít hơn Lưu ý: Chúng tôi muốn cung cấp cho bạn nội dung trợ giúp mới nhất ở chính ngôn ngữ của bạn, nhanh nhất có thể. Trang này được dịch tự động nên có thể chứa các lỗi về ngữ pháp hoặc nội dung không chính xác. Mục đích của chúng tôi là khiến nội dung này trở nên hữu ích với
bạn. Vui lòng cho chúng tôi biết ở cuối trang này rằng thông tin có hữu ích với bạn không? Dưới đây là bài viết bằng Tiếng Anh để bạn tham khảo dễ hơn. Excel không có hàm mặc định sẽ hiển thị số dưới dạng từ tiếng Anh trong một trang tính, nhưng bạn có thể thêm chức năng này bằng dán mã hàm SpellNumber sau đây vào một mô-đun VBA (Visual Basic for Applications). Hàm này cho phép bạn
chuyển đổi số lượng đô-la và phần trăm sang từ bằng công thức để 22,50 sẽ đọc dưới dạng hai mươi hai đô-la và năm mươi xu. Điều này có thể rất hữu ích nếu bạn đang dùng Excel dưới dạng mẫu để in kiểm tra. Nếu bạn muốn chuyển đổi giá trị số thành định dạng văn bản mà không hiển thị chúng như từ, hãy dùng hàm TEXT thay vào đó. Lưu ý: Microsoft
cung cấp ví dụ lập trình để minh họa chỉ, mà không cần bảo hành được thể hiện hoặc ngụ ý. Điều này bao gồm, nhưng không giới hạn, bảo đảm bán hoặc cho một mục đích cụ thể. Bài viết này giả định rằng bạn đã quen thuộc với ngôn ngữ lập trình VBA và với công cụ được dùng để tạo và để gỡ lỗi thủ tục. Microsoft hỗ trợ kỹ sư có thể giúp giải thích các chức năng của một thủ tục cụ thể. Tuy nhiên, họ sẽ không thay đổi các ví dụ này để cung cấp thêm chức năng hoặc xây dựng các thủ tục để đáp ứng yêu cầu
cụ thể của bạn. Tạo hàm SpellNumber để chuyển đổi số với các từDùng lối tắt bàn phím, Alt + F11 để mở trình soạn thảo Visual Basic (VBE). Lưu ý: Bạn cũng có thể truy nhập trình soạn thảo Visual Basic bằng
cách Hiển thị tab nhà phát triển trong ruy-băng của bạn.
Bấm tab chèn , và bấm mô-đun.
Sao chép các dòng mã sau đây. Lưu ý: Gọi là một Người dùng xác định hàm (UDF), mã này tự động hóa tác vụ về chuyển đổi số thành văn bản trong toàn bộ trang tính của bạn.
Option Explicit
'Main Function
Function SpellNumber(ByVal MyNumber)
Dim Dollars, Cents, Temp
Dim DecimalPlace, Count
ReDim Place(9) As String
Place(2) = " Thousand "
Place(3) = " Million "
Place(4) = " Billion "
Place(5) = " Trillion "
' String representation of amount.
MyNumber = Trim(Str(MyNumber))
' Position of decimal place 0 if none.
DecimalPlace = InStr(MyNumber, ".")
' Convert cents and set MyNumber to dollar amount.
If DecimalPlace > 0 Then
Cents = GetTens(Left(Mid(MyNumber, DecimalPlace + 1) & _ "00", 2))
MyNumber = Trim(Left(MyNumber, DecimalPlace - 1))
End If
Count = 1
Do While MyNumber <> ""
Temp = GetHundreds(Right(MyNumber, 3))
If Temp <> "" Then Dollars = Temp & Place(Count) & Dollars
If Len(MyNumber) > 3 Then
MyNumber = Left(MyNumber, Len(MyNumber) - 3)
Else
MyNumber = ""
End If
Count = Count + 1
Loop
Select Case Dollars
Case ""
Dollars = "No Dollars"
Case "One"
Dollars = "One Dollar"
Case Else
Dollars = Dollars & " Dollars"
End Select
Select Case Cents
Case ""
Cents = " and No Cents"
Case "One"
Cents = " and One Cent"
Case Else
Cents = " and " & Cents & " Cents"
End Select
SpellNumber = Dollars & Cents
End Function
' Converts a number from 100-999 into text
Function GetHundreds(ByVal MyNumber)
Dim Result As String
If Val(MyNumber) = 0 Then Exit Function
MyNumber = Right("000" & MyNumber, 3)
' Convert the hundreds place.
If Mid(MyNumber, 1, 1) <> "0" Then
Result = GetDigit(Mid(MyNumber, 1, 1)) & " Hundred "
End If
' Convert the tens and ones place.
If Mid(MyNumber, 2, 1) <> "0" Then
Result = Result & GetTens(Mid(MyNumber, 2))
Else
Result = Result & GetDigit(Mid(MyNumber, 3))
End If
GetHundreds = Result
End Function
' Converts a number from 10 to 99 into text.
Function GetTens(TensText)
Dim Result As String
Result = "" ' Null out the temporary function value.
If Val(Left(TensText, 1)) = 1 Then ' If value between 10-19...
Select Case Val(TensText)
Case 10: Result = "Ten"
Case 11: Result = "Eleven"
Case 12: Result = "Twelve"
Case 13: Result = "Thirteen"
Case 14: Result = "Fourteen"
Case 15: Result = "Fifteen"
Case 16: Result = "Sixteen"
Case 17: Result = "Seventeen"
Case 18: Result = "Eighteen"
Case 19: Result = "Nineteen"
Case Else
End Select
Else ' If value between 20-99...
Select Case Val(Left(TensText, 1))
Case 2: Result = "Twenty "
Case 3: Result = "Thirty "
Case 4: Result = "Forty "
Case 5: Result = "Fifty "
Case 6: Result = "Sixty "
Case 7: Result = "Seventy "
Case 8: Result = "Eighty "
Case 9: Result = "Ninety "
Case Else
End Select
Result = Result & GetDigit _
(Right(TensText, 1)) ' Retrieve ones place.
End If
GetTens = Result
End Function
' Converts a number from 1 to 9 into text.
Function GetDigit(Digit)
Select Case Val(Digit)
Case 1: GetDigit = "One"
Case 2: GetDigit = "Two"
Case 3: GetDigit = "Three"
Case 4: GetDigit = "Four"
Case 5: GetDigit = "Five"
Case 6: GetDigit = "Six"
Case 7: GetDigit = "Seven"
Case 8: GetDigit = "Eight"
Case 9: GetDigit = "Nine"
Case Else: GetDigit = ""
End Select
End Function |
|
Dán các dòng mã vào các mô-đun 1 (mã) hộp.
Nhấn Alt + Q để quay lại Excel. Hàm SpellNumber đã sẵn sàng để sử dụng. Lưu ý: Hàm này hoạt động chỉ cho sổ làm việc hiện tại. Để sử dụng hàm này trong sổ làm việc khác, bạn phải lặp lại các bước để sao chép và dán mã trong sổ làm việc đó.
Đầu trang Sử dụng hàm SpellNumber trong ô riêng lẻNhập công thức = SpellNumber(A1) vào ô mà bạn muốn hiển thị một số viết A1 nằm ở đâu vào ô có chứa số bạn muốn chuyển đổi. Bạn có thể theo cách thủ công cũng nhập giá trị như = SpellNumber(22.50).
Nhấn Enter để xác nhận công thức.
Đầu trang Lưu sổ làm việc hàm SpellNumberExcel không thể lưu sổ làm việc với các hàm macro trong định dạng sổ làm việc macro miễn phí
tiêu chuẩn (.xlsx). Nếu bạn bấm tệp > lưu. Hộp thoại dự án VB sẽ mở ra. Bấm không. Bạn có thể lưu tệp dưới dạng một Sổ làm việc có hỗ trợ macro (.xlsm) để giữ tệp của bạn ở định dạng hiện tại. Bấm Tệp > Lưu dưới Dạng.
Bấm vào menu thả xuống lưu dưới dạng , và chọn Sổ làm việc có hỗ trợ macro.
Bấm Lưu.
Đầu Trang Cần thêm trợ giúp? |
